/*----------------------------------------------------------------------------*/
/*                                                                            */
/*      Example about creating and executing a MMAIL/EMLSTMF command          */
/*      in a CLLE program                                                     */
/*                                                                            */
/*----------------------------------------------------------------------------*/
             PGM                                                                
             DCL        VAR(&SUBJECT) TYPE(*CHAR) LEN(100)                      
             DCL        VAR(&FROMNAME) TYPE(*CHAR) LEN(30)                      
             DCL        VAR(&FROMADDR) TYPE(*CHAR) LEN(50)                      
             DCL        VAR(&TONAME) TYPE(*CHAR) LEN(50)                        
             DCL        VAR(&TOADDR) TYPE(*CHAR) LEN(50)                        
             DCL        VAR(&TO) TYPE(*CHAR) LEN(3)                             
             DCL        VAR(&STMF) TYPE(*CHAR) LEN(50)                          
             DCL        VAR(&CMD) TYPE(*CHAR) LEN(1000)                         
             DCL        VAR(&CMDLEN) TYPE(*DEC) LEN(15 5) VALUE(1000)           
                                                                                
             /* ------------------------------------------------------------*/  
             /* Create the stream file to be e-mailed:                      */  
             /* /cgidev/samples/custmail2.txt                               */  
             /* ------------------------------------------------------------*/  
             DEL        OBJLNK('/cgidev/samples/custmail2.txt')                 
             MONMSG     MSGID(CPF0000)                                          
             CPYTOSTMF  +                                                       
                          FROMMBR('/qsys.lib/mmail.lib/qclsrc.file/cu+          
                          stmail2.mbr') +                                       
                          TOSTMF('/cgidev/samples/custmail2.txt') +             
                          STMFOPT(*REPLACE) STMFCCSID(819)                      
             CHGAUT     OBJ('/cgidev/samples/custmail2.txt') +                  
                          USER(*PUBLIC) DTAAUT(*RX) OBJAUT(*NONE)               
                                                                                
             /* ------------------------------------------------------------*/  
             /* Create the MMAIL/EMLSTMF command in variable &CMD           */  
             /* ------------------------------------------------------------*/  
             CHGVAR     VAR(&SUBJECT) VALUE('''Example: EMLSTMF +               
                          command in a CLLE pgm''')                             
             CHGVAR     VAR(&FROMNAME) VALUE('''Giovanni perotti''')            
             CHGVAR     VAR(&FROMADDR) +                                        
                          VALUE('''gb_perotti@easy400.net''')                   
             CHGVAR     VAR(&TONAME) VALUE('''Jeff Bonet''')                    
             CHGVAR     VAR(&TOADDR) VALUE('''jbonet@petrey.com''')             
             CHGVAR     VAR(&STMF) +                                            
                          VALUE('''/cgidev/samples/custmail2.txt''')            
             CHGVAR     VAR(&TO) VALUE('*TO')                                   
             CHGVAR     VAR(&CMD) VALUE('MMAIL/EMLSTMF SUBJECT(' +              
                          *CAT &SUBJECT *TCAT ') FROMNAME(' *CAT +              
                          &FROMNAME *TCAT ') FROMADDR(' *CAT +                  
                          &FROMADDR *TCAT ') TO((' *CAT &TOADDR +               
                          *TCAT '/' *CAT &TONAME *TCAT '/' *CAT &TO +           
                          *TCAT ')) STMF(' *CAT &STMF *TCAT ')')                
                                                                                
             /* ------------------------------------------------------------*/  
             /* Execute the MMAIL/EMLSTMF command                           */  
             /* ------------------------------------------------------------*/  
             CALL       PGM(QCMDEXC) PARM(&CMD &CMDLEN)                         
                                                                                
             RETURN                                                             
             ENDPGM